*if Juice >= 101
   *set Juice 100
*if guts >= 101
   *set guts 100
*if knowledge >= 101
   *set knowledge 100
*if observation >= 101
   *set observation 100
*if subterfuge >= 101
   *set subterfuge 100
*if Instinctive >= 101
   *set Instinctive 100
*if Instinctive < 0
   *set Instinctive 0
*if Expressive >= 101
   *set Expressive 100
*if Expressive < 0
   *set Expressive 0
*if rel_beth >= 101
   *set rel_beth 100
*if rel_prii >= 101
   *set rel_prii 100
*if rel_shauna >= 101
   *set rel_shauna 100
*if rel_grant >= 101
   *set rel_grant 100
*if rel_wyrd >= 101
   *set rel_wyrd 100
*if rel_architect >= 101
   *set rel_architect 100
*if rel_kay >= 101
   *set rel_kay 100
*if rel_teddie >= 101
   *set rel_teddie 100
*if rel_wil >= 101
   *set rel_wil 100
*if rel_gina >= 101
   *set rel_gina 100
*if rel_catalyst >= 101
   *set rel_catalyst 100
*if rel_cg >= 101
   *set rel_cg 100
*if rel_alistair >= 101
   *set rel_alistair 100
*if rel_surpass >= 101
   *set rel_surpass 100
*if rel_phalanx >= 101
   *set rel_phalanx 100
*temp stat_page 0
*temp namelist 0

*label main_stat_page

*if namedisplay = 1
    Your name is $!{fullname}. 
*elseif namedisplay = 2
    Your name is $!{fullname}, though others usually call you $!{mc_name}.
*elseif namedisplay = 3
    Your name is $!{fullname}, or it used to be.
*elseif (namedisplay = 3) and ((nickname))
    Your name is $!{fullname}. You wish anyone still called you $!{mc_name}.
*elseif (namedisplay = 4)
    Your name is $!{fullname}. You're holding onto that.
*elseif (namedisplay = 4) and ((nickname))
    Your name is $!{fullname}. You're getting used to hearing yourself called $!{mc_name} again.
*else
    It's been a while since you used your name.

*if ((met_coven)) and ((dime))
    To the Coven, you're known as Paradigm, or Dime. @{diming You've chosen to also go by $!{mask} for your superpowered affairs.|}
    
*if ((masknamed) and (not (diming)))
    Mask: $!{mask}

*if (pseudonym)
    Alias: $!{aka}

*if ((prologue)) and ((appearancedelay))
    What did you look like, back then?
    
*elseif (appearancedelay)
    @{appearancestatus |INACCESSIBLE|Now isn't the time to dwell on appearances.}
*else
    @{appearancestatus DUMMY|You are|In memories, at least, you know that you are} @{mc_height |very short|short|of medium height|tall|very tall}@{mc_build | and have a slender build| and have a toned build| and average in build| and heavyset| and have a muscular build| and your body is gaunt, almost emaciated}@{rogueperiod |.} @{specialdesc |You're about as tiny as it gets.|You're a pint-sized powerhouse!|Your size is the perfect midpoint.|Some would say you have a runner's physique.|Your sheer size is eye catching.|You're a veritable beanpole.|You're the type of massive that almost demands attention.}
    
    @{mc_eyes |You have soft brown eyes|You have ocean blue eyes|You have bottle green eyes|You have vibrant hazel eyes|You have steely grey eyes|You have unnaturally pallid, almost white eyes}@{grammarmatters |.| and }@{mc_skintone |very dark skin|dark skin|light brown skin|tan skin|fair skin|very pale skin}@{skindetail |.|, with numerous freckles.|, with noticeable weathering.|, with a number of pockmarks.|, with a good, smooth complexion.}@{featdetail | A network of thick black veins crosses your shoulders.| Strange markings resembling a hungry maw stretch across your abdomen.} @{mc_hair |Your hair is dark brown|Your hair is medium brown|Your hair is light brown|Your hair is blonde|Your hair is dirty blonde|Your hair is auburn|Your hair is red|Your hair is black|Your hair is white as bone}@{rogueand |.| and |, }@{mc_hairtype |straight|wavy|curly|you wear it naturally|textured|in a natural style}@{mc_hairlength |.|, and very short.|, and you keep it cropped short. |, and it rests just below your ears.|, and it falls to right around your chin.|, and it falls down to your shoulders.|, and it's long enough to reach the small of your back.} 
    

*if not (prologue)
    Condition: @{mc_health You are uninjured.|You are mildly injured.|You are moderately injured.|You are severely injured.|You are on death's door.|You are uninjured. Or were, anyway.}
    
    Wounds:@{injurydesc  None, for now.| Scorch to the chest.| Scorch to the chest, tendril pierced by a spike.| Hole punched in your abdominal membrane.| Widespread damage to your exoskeletal carapace.| Battered, bruised, and beaten.| Bruised to hell on account of falling off a roof like an idiot.| Bruises and cuts.| } @{recovery | You're recovering.| Nonetheless, you are recovering from your other wounds.}@{nodedesc | The destruction of a node has left you compromised.| However, the destruction of a node has left you compromised.} @{mutationdesc | An additional eye has been gouged out. | An additional eye has been gouged out.}@{getspiked | Impaled through the shoulder.|Treated, but still painful stab through the shoulder.}@{vantagebeating | A serious beating.|}@{remotemembrane | Experienced a decapitation by proxy. Leaving behind so much membrane mass doesn't feel good either.} @{juiceless  Ravaged by Juice withdrawals.|} @{surpass_stomach | Pretty sure there's a hole punched in your stomach.| Yep. Surpass sure did punch a hole in your stomach.} @{canniganked | A nasty gash across the back.} @{pocketsand | Facial lacerations.} @{golfball  | Who would have thought a golf ball could hurt this much?|You have verified that taking a golf ball to the face hurts like hell.} @{kniferailgun | A knife railgunned into your abdomen.} @{shrapnel |Your left side is a mess of shrapnel-esque wounds.} @{blownup | Also, you kinda just got blown up.}

*else
    @{prologuehealth You are uninjured. Or were, anyway.|You are on death's door, your right arm and chest slashed to ribbons.|You are exhausted and injured, with a thoroughly busted nose.|You are on death's door, your right shoulder bitten down to the bone.}
    
*if (not (prologue)) and (fighting_style <4)
    Combat Style: @{fighting_style Hand-to-hand fighter|Adaptable improviser|Power wielder|DUMMY} 
    
    Power Speciality: @{speciality Semi-independent nodes|Wild mutation|Hardened carapace|Unknown}
    
*if (prologue)
    Combat Style: Plucky underdog
    
    @{funspeciality Power Speciality: Powers?|Best Bench Press: Grant. On a bet.|Trivia Contest Level: Expert Plus|Unsubstantiated Rumour: Eyes enhanced with the genes of a bird of prey.|Dubious Claim to Fame: Once snuck past security inside a cardboard box.}
    

*stat_chart
    opposed_pair Instinctive
           Methodical
    opposed_pair Expressive
           Reserved

*if (not (prologue))
    *stat_chart
        percent Juice

*if not (opening)
    [b]@{prologue Old |}Skills[/b]
    *stat_chart
          percent guts Guts
          percent knowledge Knowledge
          percent observation Observation
          percent subterfuge Subterfuge
          
[b]Relationships@{prologue , before everything.|}[/b]
*if (prologue)
    *stat_chart
        percent rel_beth Beth
        percent rel_prii Prii
        percent rel_shauna Shauna
        percent rel_grant Grant

*if ((met_wa)) and (not (prologue))
    *stat_chart
        percent rel_wyrd @{wyrdisplay Wyrd | Mallory (Wyrd)}
        percent rel_architect @{archdisplay Architect | Dion (Architect)}

*if (met_ktg)
    *stat_chart
        percent rel_kay Kay (Rampage)
        percent rel_teddie Teddie (Fracture)
        percent rel_wil Wil (Ghoul)
        
*if (met_gina)
    *stat_chart
        percent rel_gina Gina (Flash Mob)

*if (met_coven)
    *stat_chart
        percent rel_catalyst Catalyst
        
*if (met_cg)
    *stat_chart
        percent rel_cg @{cgdisplay Control Group | CG | Cee | Mirella (Control Group)}
*if (met_alistair)
    *stat_chart
        percent rel_alistair @{alidisplay Pasta Ninja |Pasta La Vista |Alistair}
        
*if met_surpass = 1
    *stat_chart
        percent rel_surpass Surpass

*if met_surpass = 2
    *stat_chart
        percent rel_surpass Liz
*if met_phalanx = 1
    *stat_chart
        percent rel_phalanx Beth


*goto navigationmenu
*label statguide

[b]Skills[/b]

[b]Guts:[/b] Physical fitness, stamina, and all-around presence. High guts means you're strong, enduring, and forceful.

[b]Knowledge:[/b] Researching, memory, and convincing rhetoric. High knowledge means you're persuasive, a good fact finder, and retain information well.

[b]Observation:[/b] Acuity of vision and hearing, reading other people. High observation means you're perceptive, spot the small details, and pick up on the tells of others.

[b]Subterfuge[/b] Quick and quiet movement, lockpicking, and deception. High subterfuge means you're stealthy, a good liar, and handy at breaking and entering.

*if (fighting_style <4)
    [b]Expertise[/b]
    
    [b]Combat Style:[/b] The character's expertise in masked fighting.
    
    [i]Hand-to-hand fighter:[/i] Physical brawling, up close and personal. Taking on opponents in fistfights with technique and discipline.
    
    [i]Adaptable improviser:[/i] Quick thinking in a pinch and on the fly. Responding flexibly to changing situations.
    
    [i]Power wielder:[/i] Creative use and fine control of powers. Pushing powers to new limits.
    
    *if (speciality <4)
        [b]Speciality:[/b] The character's unique power technique.
        
        [i]Semi-independent nodes:[/i] Creation of one or more creatures ('nodes') from within the body. Nodes act largely on hunting instinct, but can be influenced to a certain extent. Thoughts and sensations are shared via an empathic link.
        
        [i]Wild mutation:[/i] Inducing rapid and largely uncontrolled changes of physiology to increase combat capabilities. Makes the user much more dangerous, but it's not exactly subtle.
        
        [i]Hardened carapace:[/i] Extending and improving the existing membrane formed by the powers. The carapace is incredibly sturdy and able to absorb a great deal of punishment. However, sensations connect directly to the armour, and its weight can be detrimental.

[b]Personality[/b]

[b]Instinctive/Methodical:[/b] Do you tend to go with your gut, or prefer to work through issues step by step? Instinctive characters react in the moment and don't overthink, but can sometimes put themselves in sticky situations. Methodical characters plan effectively and can slow down situations to take control, but are sometimes late to respond to threats.

[b]Expressive/Reserved:[/b] Do you wear your heart on your sleeve, or keep your emotions under wraps? Expressive characters show their personality freely, but aren't always great at keeping calm. Reserved characters have steady nerves and a good poker face, but can come across as cold and unenthusiastic.
*goto navigationmenu

*label castlist

*if (met_wa)
    [b]@{teamdisplay Unnamed Villain Group|The Altruists}[/b]
    *line_break
    A new team of villains that is beginning to make a splash in the city of Alderbrook. @{teamdisplay |You've joined them under Hypothesis's orders.} 
    
    [b]Architect @{archdisplay |(Dion)}[/b]
    *line_break
    An enigmatic newcomer with an unknown agenda. Serious and businesslike. @{archdisplay |A little less strait-laced out of costume.}
    *line_break
    Appearance: @{archdisplay |(Regular) Black. Short afro fade hair. Well-trimmed beard. Roughly late twenties.} @{archdisplay |(Architect)} Medium height and build. Wears a featureless white helmet, a grey longcoat, and boots.
    *line_break
    Power: Geometric energy projections
    *line_break
    Status: Active
    
    [b]Wyrd @{wyrdisplay |(Mallory/Mal)}[/b]
    *line_break
    An irreverent smartmouth. Difficult to read; just how genuine are all their jokes?
    *line_break
    Appearance: Korean-American, you think. @{(malpower = 1) Slender. Dark, floppy hair.|The specifics vary, thanks to their power. } @{wyrdisplay Street clothes, including a leather jacket. Domino mask.|Tends towards street clothes. Their costume consists solely of adding a domino mask.}
    *line_break
    Power: @{malpower Durability|Shapeshifting|Self-biokinesis?}
    *line_break
    Status: Active

*if (met_ktg)
    [b]Ghoul ($!{wname}/Wil)[/b]
    *line_break
    Calm, genial, and thoughtful. Looks a lot creepier in costume than ${whe} actually is.
    *line_break
    Appearance:  (Regular) Tall. Lean, but muscled. Ghostly pale. Icy blue eyes. Short, ash blonde hair. Punk, gothic style, including black lipstick and piercings. Has tattoos, apparently. (Ghoul) Tattered cloak with ribbons of black cloth, concealing ${whis} silhouette. Half-mask, gnashing teeth design.
    *line_break
    Power: Draining touch
    *line_break
    Status: Active
    
    [b]Fracture (Teddie)[/b]
    *line_break
    Prickly and antisocial, keeps others at arm's length. Kay's closest friend.
    *line_break
    Appearance: (Regular) Fairly short and lacking bulk. White. Short brown hair. Piercing green eyes. Numerous erratic protrusions of bone, pushing straight through skin. Wears loose, flexible clothing. (Fracture) Further growths, creating a mask/helmet and various clubbing/slashing weapons.
    *line_break
    Power: Bone morphing
    *line_break
    Status: Active
    
    [b]Rampage (Kay)[/b]
    *line_break
    A shy but energetic and determined girl who tries to look on the bright side. Teddie's closest friend.
    *line_break
    Appearance: (Regular) Stocky, husky build. Farmer's tan. Fluffy, grey-white hair. Curling horns. Amber eyes with horizontal pupils. Casual dresser. (Rampage) Sleeveless hoodie and bike shorts. Bandanna around her face.
    *line_break
    Power: Force absorption and charging 
    *line_break
    Status: Active

*if (met_gina)
    [b]Flash Mob (Gina)[/b]
    *line_break
    A small time villain looking for a crew. Mischievous and a little hyperactive.
    *line_break
    Power: Divides into small creatures
    *line_break
    Status: Active

*if (covendisplay)
    [b]The Coven[/b]
    *line_break
    A small organisation formed by Hypothesis in order to pursue his personal goals. The specifics of those goals are a mystery to all save Hypothesis himself.
    
    [b]Hypothesis[/b]
    *line_break
    Scholarly and science-focused. Your benefactor. Or captor, depending on how you look at it. 
    *line_break
    Appearance: Formerly fit, going a little to seed. White. Short dark hair, greying to white at the temples and throughout his full beard. Wire-framed spectacles. Almost resembles a professor. Fifties (estimated). 
    *line_break
    Power: Unknown, possibly involves chemical synthesis
    *line_break
    Status: Active
    
    [b]Catalyst[/b]
    *line_break
    The Coven's lieutenant. Holds a particular hatred towards you.
    *line_break
    Appearance: Short, but muscular. Black. Very dark eyes. Shaven head. Wears a-shirts, jeans, and work boots. Thirties (estimated).
    *line_break
    Power: Physical echoes
    *line_break
    Status: Active, unfortunately
    
    [b]Variable (Airy)[/b]
    *line_break
    An enthusiastic (guileless?) member of the Coven. Always willing to offer a helping hand. Bad at gauging if said hand is wanted or needed.
    *line_break
    Appearance: Chubby. Very dark skin. Buzzed white hair. Flashy dresser.
    *line_break
    Power: Self displacement
    *line_break
    Status: @{airystatus Field operations|Undercover with the Businessmen}
    
    [b]Control Group/$!{cg} @{(cgstatus != 1) (Libra)|} @{(cgdisplay = 4)  (Mirella)|}[/b]
    *line_break
    Your handler and former trainer, sly and playful, but can flip to all-business on a, ahem, dime.
    *line_break
    Appearance: @{(cgstatus != 1) (Regular) Short and compact with muscle. Olive-skinned. Minor scarring. Curly brown hair. Never without a leather jacket.|} @{(cgstatus != 1) (Libra) Full-face mask. Gloves. Motorcycle leathers. Hair worn in a tight bun.|}
    *line_break
    Power: Perfect balance
    *line_break
    Status: @{cgstatus Field operations |Undercover hero}
    
    [b]Lullaby[/b]
    *line_break
    Freelancer working with the Coven. Security specialist.
    *line_break
    Appearance: Slender. Pallid. Dark, empty eyes. Sandy blonde hair. Dresses smart casual.
    *line_break
    Power: Soporific singing 
    *line_break
    Status: Active
    
    [b]Gremlink:[/b]
    *line_break
    Freelancer working with the Coven. Technological expert.
    *line_break
    Appearance: Skinny. Multiracial (black, east asian). Braids. Tech-integrated glasses. Self-installed and modified cybernetics. 
    *line_break
    Power: Augmented
    *line_break
    Status: Active
    
*if (arcade)
    [b]The Glory Hounds[/b]
    *line_break
    Alderbrook's premier hero team. Adopted their name as an ironic badge of pride after a DPR official disparagingly referred to them as a bunch of glory hounds. Known to be less by the book than a lot of heroes, and their position in the city has been on shaky ground after a major clash resulted in widespread property damage.
    
    [b]Arcade[/b]
    *line_break
    The youngest member of the Hounds. Loves to banter and crack jokes, but a dedicated hero. 
    *line_break
    Appearance: Leanly muscled. Asian-American. Wears black spandex with red accents and a mask which shows most of his boyishly handsome face. @{arcade_nose A little less so after you broke his nose.|}
    *line_break
    Power: Laser blasts
    *line_break
    Status: Active
    
    [b]Enfilade[/b]
    *line_break
    A new addition to the Hounds. An augment who takes her job extremely seriously.
    *line_break
    Appearance: Burly build. Pale skinned. Buzzcut hair. Doesn't wear a mask. Wears grey-patterned fatigues without sleeves. Cybernetics visibly woven through her arms.
    *line_break
    Power: Augmented 
    *line_break
    Status: Active    

*if (surpasshere)
    [b]Surpass[/b]
    *line_break
    The Hounds' heavy hitter. Cocky, boisterous, and always spoiling for a good fight.
    *line_break
    Appearance: Towering, well over 6ft tall. Ripples with muscle. Medium brown skin. Wears a shemagh and a singlet. Welcome to the gunshow.
    *line_break
    Power: Superhuman strength, speed, and durability
    *line_break
    Status: Active

*if (houndsmet)
    [b]Vantage[/b]
    *line_break
    Leader and tactician of the Hounds. Both an activist and a hero.
    *line_break
    Appearance: Average height and build. Dark skin. Natural hair worn in a disciplined bun. Goes maskless. Wears a white and blue bodysuit. Wields dual batons.
    *line_break
    Power: Precognitive simulation
    *line_break
    Status: Active
    
    [b]Portrait[/b]
    *line_break
    Hounds member. Responsible for a majority of their non-heroing outreach.
    *line_break
    Appearance: Slight build. Olive-skinned. Venetian style mask. Bodysuit styled after a painter's apron. Wields a quarterstaff slash paintbrush.
    *line_break
    Power: Animated constructs
    *line_break
    Status: Active
    
    [b]Phalanx[/b] @{(bethstatus = 3) (Beth)|}
    *line_break
    DPR defector as of the Zone incident. Stoic and professional. @{(bethstatus = 3) Also one of your former AdVenture buddies.|}
    *line_break
    Appearance: @{(bethstatus = 3) (Regular) Older, greyer, and more scarred than you remember.|} @{(bethstatus = 3) (Phalanx)|} Full suit of armour, including helm, lance, and a shield with a V-shaped design. Wears a small scarf.
    *line_break
    Power: Ferrokinesis
    *line_break
    Status: Active
    
*if (met_alistair)
    [b]Others[/b]
    
    [b]@{alidisplay Pasta Ninja|Pasta La Vista|Alistair}[/b]
    *line_break
    *if alidisplay != 3
        A mysterious individual who dropped a container of pasta on your doorstep.
        *line_break
        Power: Lasagne crafting
        *line_break
        Status: Cooking something up, presumably
    *else
        *line_break
        A charity worker who stumbled across your hideout. Very genuine. Very dangerous.
        *line_break
        Appearance: Tall and muscular. Black. Braids his dark hair into a loose tail. A good dresser. Wears glasses.
        *line_break
        Power: Home cooking
        *line_break
        Status: Being too nice for his own good
        

*if (patrol > 1)
    [b]Wesson Parks Patrol[/b]
    *line_break
    A trio of heroes who have taken it upon themselves to defend Wesson Parks.
    
    [b]Ranger[/b]
    *line_break
    A bombastic hero who has watched way too many superhero cartoons.
    *line_break
    Appearance: Short. Mousy brown hair. Green fatigues. Ski mask. Wields an odd weapon that's part bat, part sword.
    *line_break
    Power: @{patrol DUMMY| Camouflage |Limited invisibility/illusion}
    *line_break
    Status: @{patrolstatus Active|Out of Action}
    
    [b]Mis[/b]
    *line_break
    Previously half of the duo known as Mis/Hit, smalltime independents.
    *line_break
    Appearance: Lean, toned build. Sports style body armour, including elbow and knee pads. Red bullseye stencilled on her chest.
    *line_break
    Power: Enhanced evasion
    *line_break
    Status: @{patrolstatus Active|Out of Action}
    
    [b]Hit[/b]
    *line_break
    Previously half of the duo known as Mis/Hit, smalltime independents.
    *line_break
    Appearance: Skinny. Sports style body armour, including elbow and knee pads. Red crosshair stencilled on his chest. Wields a slingshot.
    *line_break
    Power: Perfect accuracy
    *line_break
    Status: @{patrolstatus Active|Out of Action}
    
*if (businessmen)
    [b]The Businessmen[/b]
    *line_break
    Villainous group with their fingers in many pies. Play all sides as brokers of information and illegal goods.
    
    [b]Management[/b]
    *line_break
    Mid-ranking Businesswoman. Arrogant, ruthless, and occasionally petty. Main liaison to the Altruists.
    *line_break
    Appearance: Black. Coily dark hair. Domino mask. Wears a pantsuit.
    *line_break
    Power: Unknown
    *line_break
    Status: Filing reports.
    
    [b]Mr. White[/b]
    *line_break
    Muscle for the Businessmen. Professional, but worn down thanks to age and back-alley cybernetics.
    *line_break
    Appearance: Tall and broad-shouldered. White. Weathered face. Short, greying hair. Filament-like strands spooling from wrists and chin. Wears suspender pants with a short-sleeved button-up. Domino mask.
    *line_break
    Power: Augmented
    *line_break
    Status: Active
    
    [b]Scour[/b]
    *line_break
    The Businessmen's most dangerous weapon. Cold, callous, and deadly.
    *line_break
    Appearance: Very thin. Often lightly dusted in sand. Wears a very expensive suit and domino mask.
    *line_break
    Power: A living sandstorm
    *line_break
    Status: Active
   
*if (scum)
    [b]S.C.U.M.[/b]
    *line_break
    Alderbrook gang known for aggressiveness and violent crime. Severely damaged by the Zone incident, but survived and gradually rebuilt. No, the letters don't stand for anything.
    
    [b]Rocket[/b]
    *line_break
    Leader of S.C.U.M., notorious for killing her predecessor. Brash, loudmouthed, and about as temperamental as it gets.
    *line_break
    Appearance: White. Bright crimson/orange costume. Long, neon red hair. Wears a huge pair of flame-patterned sunglasses in lieu of a mask. Wears a bandolier of golf balls.
    *line_break
    Power: Launches projectiles
    *line_break
    Status: Active
    
    [b]Spring Breaker[/b]
    *line_break
    A prolific thief and known murderer. Steals jewellery and other finery. Oscillates between arrogance and petulant anger, depending whether things are going her way.
    *line_break
    Appearance: Has a light, meticulously even tan. Conventionally attractive but wears far too much makeup. No real costume, instead donning the poorly repaired and ill-fitting clothing of her victims, the more expensive the better.
    *line_break
    Power: Moisture manipulation
    *line_break
    Status: Active
    
    [b]Insider[/b]
    *line_break
    One of the less notorious members of S.C.U.M., keeping a generally lower profile. Major inferiority complex.
    *line_break
    Appearance: Unhealthily pale. Wears a fedora, trenchcoat, and fingerless gloves. Wraps leather strips around his face for a mask.
    *line_break
    Power: Unclear, seems to involve tracking.
    *line_break
    Status: Active
    
    [b]Conquest[/b]
    *line_break
    Prodigal son of veteran DPR hero Quartermaster. Relatively recent addition to S.C.U.M. Reckless and cocky.
    *line_break
    Appearance: Black. Tall, but gawky; hasn't filled out yet. Costume consists of a plated vest and armoured pants. Two sheaths crossed over his back.
    *line_break
    Power: Spectral weaponry
    *line_break
    Status: Incarcerated
    
    [b]Cannibal[/b]
    *line_break
    On several DPR most wanted lists, Cannibal's presence often keeps augments from the field for their own safety.
    *line_break
    Appearance: A patchwork monstrosity of cybernetics, almost more metal than flesh. Probably(?) white. Genuinely difficult to tell.
    *line_break
    Power: Numerous jury-rigged, cannibalised augmentations.
    *line_break
    Status: Active
    
*if (adventure)
    [b]Urban AdVenture [/b]
    *line_break
    An urban exploration group which hosts a relatively popular video channel. Once upon a time, you were a member.
    
    [b]Prii[/b]
    *line_break
    The de facto leader. Charming, enthusiastic, and mischievous.
    *line_break
    Appearance: Slim. White. Hazel eyes. Sharp features with high cheekbones. Mid-length brown hair, often decorated. Multiple ear piercings. Eclectic dresser who likes to mix and match.
    *line_break
    *if (priip)
        Power: @{speciality Plantlike creatures|Wild mutation|Hardened carapace|dummy}
        *line_break
    Status: @{priistatus Buoyant as ever|Deceased|Presumed dead|Dead. You know they're dead.}
    
    [b]Beth (Elizabeth)[/b]
    *line_break
    The planner. Snarky and sometimes biting, with a soft centre.
    *line_break
    Appearance: Short and slight. Very pale. Short black hair. Blue eyes. Goth librarian chic. 
    *line_break
    *if (bethp)
        Power: Telekinetic disc
        *line_break
    Status: @{bethstatus Weaponising eye rolls|Unknown|Making your life incredibly complicated. See Phalanx.}
    
    [b]Grant[/b]
    *line_break
    The mood maker. Bold and rarely takes things seriously; prime suspect for pranks.
    *line_break
    Appearance: Middling height and build. Suntanned. Long, sandy blond hair usually pulled into a tail. Conventionally handsome. Dresses like its party time.
    *line_break
    Status: @{grantstatus Teasing everyone in sight|Deceased|Unknown|Alive, 'last Beth saw him'}
    
    [b]Shauna[/b]
    *line_break
    The creative. Shy, but has a playful side. Always looks out for her friends.
    *line_break
    Appearance: Lanky, but athletic and toned. Light brown skin; darker birthmarks on the neck and jawline. Deep brown eyes, dark brown hair, wavy and textured. Oval glasses. Wears scarves. A bit of a shapeless, 'frumpy' dresser.
    *line_break
    Status: @{shaunastatus Armed and dangerous (with a camera)|Deceased|Unknown|Presumed dead|Alive, 'last Beth saw her'}

*goto navigationmenu

*label toneindicators

This game features the option for tone indicators for choices that entail physical and/or romantic attraction towards other characters. If enabled, these choices will be clearly marked in square brackets.

Note that it is not mandatory to flirt or otherwise express immediate interest in potential romance options at every opportunity in order to eventually pursue a relationship with them.

Indicators will display as 'passive' if the choice involves the player character thinking about feelings of attraction without acting on them. In some instances, the PC may not realise attraction is what they're feeling!

Enable tone indicators?
*fake_choice
    #Yes.
        *set ftone true
        Tone indicators now enabled!
    #No.
        *set ftone false
        Tone indicators now disabled!
*page_break
*set stat_page 0
*goto main_stat_page 

*label namelist
[i]Villain Juice[/i] features a lot of named characters, many of whom also have code names. Check here if you have concerns about doubling up with the name of your PC.

Main characters are the central cast of the game, appearing frequently and/or in major roles.

Secondary characters are less significant, appearing in fewer scenes and lesser roles.

Minor characters are unimportant one-offs or only mentioned in passing.
*choice
    #Regular names.
        *label regnames
        [b]Main Characters[/b]
        *line_break
        Alistair Adeniji 
        *line_break
        Beth* Volkova
        *line_break
        Dion
        *line_break
        Grant Glenn
        *line_break
        Kay
        *line_break
        Mallory (Mal)
        *line_break
        Mirella
        *line_break
        Prii Hawthorne
        *line_break
        Sammy Niwa
        *line_break
        Shauna Caldwell
        *line_break
        Teddie
        *line_break
        Wil, AKA Wilson, Wilma, or Willow
        
        There* is a special case for selecting 'Elizabeth' as one's name.
        
        [b]Secondary Characters[/b]
        *line_break
        Alice
        *line_break
        Camilla
        *line_break
        Chris
        *line_break
        Federico, AKA Federica, Rico, or Rica
        *line_break
        Freddy
        *line_break
        Kelly
        *line_break
        Knight
        *line_break
        Miguel
        *line_break
        Mi-Yeon
        *line_break
        Otto
        *line_break
        Ramón Ramos
        *line_break
        Tai
        
        [b]Minor Characters[/b]
        *line_break
        Castillo
        *line_break
        Danny
        *line_break
        Luke Schofield 
        *line_break
        Heung
        *line_break
        Maya
        *line_break
        Nat
        *line_break
        Nathan Fenwick
        *line_break
        Sawicki
        *line_break
        Shannon
        *line_break
        Shun
        *line_break
        Simons
        *line_break
        Vasanti McCarthy
        *line_break
        Watson
        *line_break
        Zhang
        
        *choice
            #View mask names.
                *goto masknames
            #Return to the main stat page.
                *set stat_page 0
                *goto main_stat_page
                
    #Code/mask names.
        *label masknames
        [b]Main Characters[/b]
        *line_break
        Arcade
        *line_break
        Architect
        *line_break
        Catalyst
        *line_break
        Control Group
        *line_break
        Enfilade
        *line_break
        Fracture
        *line_break
        Ghoul
        *line_break
        Hypothesis
        *line_break
        Phalanx
        *line_break
        Portrait
        *line_break
        Rampage
        *line_break
        Surpass
        *line_break
        Vantage
        *line_break
        Wyrd
        
        [b]Secondary Characters[/b]
        *line_break
        Cannibal
        *line_break
        Carnival
        *line_break
        Gremlink
        *line_break
        Hit
        *line_break
        Insider
        *line_break
        Knight
        *line_break
        Libra
        *line_break
        Lullaby
        *line_break
        Management
        *line_break
        Mis
        *line_break
        Mr. White
        *line_break
        Network
        *line_break
        (The) Project
        *line_break
        Quint
        *line_break
        Ranger
        *line_break
        Rocket
        *line_break
        Scour
        *line_break
        Spring Breaker
        *line_break
        Variable
        
        [b]Minor Characters[/b]
        *line_break
        Abstract
        *line_break
        Categoric
        *line_break
        Conquest
        *line_break
        Conspirator
        *line_break
        Dart
        *line_break
        Empirical
        *line_break
        Giftwrap
        *line_break
        Glamoura
        *line_break
        Hallucinogem
        *line_break
        Solute
        *line_break
        Quartermaster
        *line_break
        Vault
        
        *choice
            #View regular names.
                *goto regnames
            #Return to the main stat page.
                *set stat_page 0
                *goto main_stat_page
    #Return to the main stat page.
        *set stat_page 0
        *goto main_stat_page
        
     
    
*label navigationmenu
*choice
     *if (stat_page != 0) #Return to the main stat page.
        *set stat_page 0
        *goto main_stat_page
     *if (stat_page != 1) #Stats Guide.
        *set stat_page 1
        *goto statguide
     *if (stat_page != 2) #Cast List.
        *set stat_page 2
        *goto castlist
     *if (stat_page != 3) #Tone Indicators.
        *set stat_page 3
        *goto toneindicators
     *if (stat_page != 4) #Character Names (minor spoilers).
        *set stat_page 4
        *goto namelist